feat: add initial config for kachu-pc

drvs/sddm-astronaut-theme.nix

@@ -0,0 +1,10 @@
+{pkgs}:
+(pkgs.sddm-astronaut.override {
+  embeddedTheme = "black_hole";
+}).overrideAttrs (oldAttrs: {
+  installPhase =
+    oldAttrs.installPhase
+    + ''
+      chmod u+w $out/share/sddm/themes/sddm-astronaut-theme/Backgrounds/
+    '';
+})

drvs/wezterm-stable-bin.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  autoPatchelfHook,
+  fontconfig,
+  libxkbcommon,
+  libGL,
+  libglvnd,
+  wayland,
+  libx11,
+  libxcb,
+  zlib,
+  dbus,
+  vulkan-loader,
+  openssl,
+  xcbutil,
+  xcbutilimage,
+}:
+stdenv.mkDerivation rec {
+  pname = "wezterm-bin";
+  version = "20240203-110809-5046fc22";
+
+  src = fetchurl {
+    url = "https://github.com/wezterm/wezterm/releases/download/${version}/wezterm-${version}.Ubuntu22.04.tar.xz";
+    hash = "sha256-FCy0beZIIAuFLMSx2TLmuPKp08VfbcWvRLbU7rk4X1w=";
+  };
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+  ];
+
+  buildInputs = [
+    stdenv.cc.cc.lib
+    fontconfig
+    libxkbcommon
+    libGL
+    libglvnd
+    wayland
+    libx11
+    libxcb
+    zlib
+    dbus
+    vulkan-loader
+    openssl
+    xcbutil
+    xcbutilimage
+  ];
+
+  runtimeDependencies = [
+    libGL
+    libglvnd
+  ];
+
+  installPhase = ''
+    mkdir -p $out
+
+    # Копируем готовую структуру из папки usr архива
+    cp -r usr/bin $out/
+    cp -r usr/share $out/
+
+    # Исправляем пути в desktop-файле для интеграции с KDE
+    find $out/share/applications -name "*.desktop" -exec sed -i "s|Exec=wezterm-gui|Exec=$out/bin/wezterm-gui|g" {} +
+  '';
+
+  meta = with lib; {
+    description = "A GPU-accelerated cross-platform terminal emulator (Natively patched binary)";
+    homepage = "https://wezfurlong.org/wezterm/";
+    license = licenses.mit;
+    platforms = platforms.linux;
+    mainProgram = "wezterm";
+  };
+}